设计一个数字电子钟，用单片机最容易做，电路也比较简单。采用proteus仿真实现就更方便了，用一个8位一体的共阴数码管，可以显示出小时，分，秒，并有3个按键用来调时，如下为电子钟仿真图。
呵呵呵，你走运了，我做过课后作业，有问题以再问我
带调时间的数字钟
定时器1s触发中断一次，计时+1，主程序负责传输时间到led及检测按键，其他见注释。
左面有器件列表，这个是protenus仿真
ORG 0000H
AJMP MAIN
ORG 000BH
LJMP T0INT
ORG 001BH
LJMP T1INT
ORG 0100H
MAIN: MOV TMOD,#51H ;T0定时器方式1，T1计数器方式1
MOV TCON,#54H ;开定时计数器，T1边沿触发
MOV TH0,#4BH ;（65536-19453）*1.085=50MS，晶振11.0592MHZ
MOV TL0,#0FFH ;去掉了装载初值用的机器周期
MOV TH1,#0FFH ;满10溢出，1S
MOV TL1,#0F6H
MOV IE,#8AH ;开中断
MOV R7,#04H ;预置13:58:00 的时
MOV R2,#13H
MOV A,R2
LCALL DISPLAY
MOV R7,#02H ;预置13:58:00 的分
MOV R1,#58H
MOV A,R1
LCALL DISPLAY
CHECKKEY:LCALL KEY1
LCALL KEY2
LCALL KEY3
LCALL KEY4
AJMP CHECKKEY
;;;;;;;;;;中断;;;;;;;;;;;;;;;;;;;;;;
T0INT: MOV TH0,#4BH
MOV TL0,#0FDH
CPL P2.0
RETI
T1INT: MOV TH1,#0FFH
MOV TL1,#0F6H
PUSH ACC
CPL P2.1
MOV A,R0 ;R0计秒钟，通过A调整为BCD码
ADD A,#1
DA A
MOV R0,A
CJNE R0,#60H,MIAO
MOV R0,#00H
MOV A,R1 ;R1计分钟，通过A调整为BCD码
ADD A,#1
DA A
MOV R1,A
CJNE R1,#60H,FEN
MOV R1,#00H
MOV A,R2 ;R2计时钟，通过A调整为BCD码
ADD A,#1
DA A
MOV R2,A
CJNE R2,#24H,SHI
MOV R2,#00H
SHI: MOV R7,#04H
MOV A,R2
LCALL DISPLAY
FEN: MOV R7,#02H
MOV A,R1
LCALL DISPLAY
MIAO: MOV R7,#01H
MOV A,R0
LCALL DISPLAY
POP ACC
RETI
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;显示
;A--显示BCD码,R7--选择数码管
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
DISPLAY:MOV P1,R7
MOV SCON,#0
MOV SBUF,A
JNB TI,$
CLR TI
RET
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;按键检测与执行程序
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
KEY1: JB P0.0,DONE1 ;检测P0.0口按键，若没按下，则结束
LCALL DELAY ;延时去抖
JB P0.0,DONE1 ;再次检测，若没按下，则结束
JNB P0.0,$ ;等待按键松开
CPL EA ;开关定时中断
DONE1: RET
KEY2: JB EA,DONE2 ;若EA=1，则调时间按键无效
JB P0.1,DONE2 ;检测P0.0口按键，若没按下，则结束
LCALL DELAY ;延时去抖
JB P0.1,DONE2 ;再次检测，若没按下，则结束
MOV A,R2 ;R2计时钟+1,通过A调整为BCD码
ADD A,#1
DA A
CJNE A,#24H,CHECK2
MOV A,#00H
CHECK2: MOV R2,A
MOV R7,#04H ;显示改后的时间
MOV A,R2
LCALL DISPLAY
DONE2: RET
KEY3: JB EA,DONE3
JB P0.2,DONE3
LCALL DELAY
JB P0.2,DONE3
MOV A,R1 ;R1计分钟+1,通过A调整为BCD码
ADD A,#1
DA A
CJNE A,#60H,CHECK3
MOV A,#00H
CHECK3: MOV R1,A
MOV R7,#02H ;显示改后的时间
MOV A,R1
LCALL DISPLAY
DONE3: RET
KEY4: JB EA,DONE4
JB P0.3,DONE4
LCALL DELAY
JB P0.3,DONE4
MOV A,R0 ;R0计秒钟+1,通过A调整为BCD码
ADD A,#1
DA A
CJNE A,#60H,CHECK4
MOV A,#00H
CHECK4: MOV R0,A
MOV R7,#01H ;显示改后的时间
MOV A,R0
LCALL DISPLAY
DONE4: RET
;;;;;;;;DELAY;;;;;;;;;;;;;;;;;;
DELAY: MOV R4,#0FFH
DL: MOV R5,#0FFH
DJNZ R5,$
DJNZ R4,DL
RET
END
巧了，国亲无聊做了一个玩玩，给你看看把，其实电子钟挺简单的，下面是程序：
#includereg52.h
#define uchar unsigned char
#define uint unsigned int
sbit ch=P3^2;
sbit key=P3^5;
sbit key1=P3^4;
uchar t0,numn,numy,numr,nums,numf,numm,sw,w,q,b,s,g,sw1,w1,q1,b1,s1,g1,rq,temp,x;
uint u;
void init();
void display(uchar,uchar,uchar,uchar,uchar,uchar);
void delay(uint z)
{
uint x,y;
for(x=z;x0;x--)
for(y=70;y0;y--);
}
void main()
{
init();
while(1)
{
if(rq==1)
{
if(rq==1)
display(sw,w,q,b,s,g);
}
else if(rq==2)
{
if(rq==2)
display(sw1,w1,q1,b1,s1,g1);
}
else if(rq==3)
{
if(rq==3)
display(w,w,w,w,w,w);
}
else if(rq==4)
{
uchar i;
temp=0x01;
for(i=0;i8;i++)
{
P1=~temp;
delay(100);
temp=1;
}
temp=0x80;
for(i=0;i8;i++)
{
P1=~temp;
delay(100);
temp=1;
}
temp=0x01;
for(i=0;i8;i++)
{
P1=temp;
delay(100);
temp=1;
}
temp=0x7F;
for(i=0;i8;i++)
{
P1=temp;
delay(100);
temp=1;
}
}
else
rq=1;
}
}
void init()
{
rq=1;
x=1;
nums=22;
numf=0;
numm=0;
numn=9;
numy=10;
numr=15;
TMOD=0x11;
TH0=(65536-50000)/256;
TL0=(65536-50000)%256;
IT0=1;
IT0=2;
EA=1;
EX0=1;
EX1=1;
ET0=1;
TR0=1;
ET1=1;//IE=0x82 //CPU开中断,CT0开中断
}
void timer0() interrupt 1
{
TH0=(65536-50000)/256;
TL0=(65536-50000)%256;
t0++;
if(key==0)
{
delay(50);
if(key==0)
{
x++;
while(key==0);
}
}
if(x==2rq==1)
{
//P0=0xf3;
if(key1==0)
{
numf++;
while(key1==0);
}
}
else if(x==3rq==1)
{
// P0=0xfc;
if(key1==0)
{
nums++;
while(key1==0);
}
}
else if(x==2rq==2)
{
// P0=0xcf;
if(key1==0)
{
numr++;
while(key1==0);
}
}
else if(x==3rq==2)
{
// P0=0xf3;
if(key1==0)
{
numy++;
while(key1==0);
}
}
else if(x==4rq==2)
{
// P0=0xfc;
if(key1==0)
{
numn++;
while(key1==0);
}
}
else
{
x=1;
}
if(t0==20)
{
t0=0;
numm++;
}
if(numm==60)
{
numm=0;
numf++;
}
if(numf==60)
{
for(u=500;u0;u--)
{
bell=0;
delay(1);
bell=1;
delay(1);
}
numf=0;
nums++;
}
if(nums==24)
{
nums=0;
numr++;
}
if(numr==30)
{
numr=0;
numy++;
}
if(numy==12)
{
numy=0;
numn++;
}
if(numn==100)
{
numn=0;
}
g=numm%10;
s=numm/10;
b=numf%10;
q=numf/10;
w=nums%10;
sw=nums/10;
g1=numr%10;
s1=numr/10;
b1=numy%10;
q1=numy/10;
w1=numn%10;
sw1=numn/10;
}
void exert0() interrupt 0
{
delay(50);
rq++;
while(ch==0);
}
void t0int() interrupt 3
{
TR1=0;
bell=!bell;
TH1=timer0h;
TL1=timer0l;
TR1=1;
}
void exert1() interrupt 2
{
rq=100;
}
void display(uchar sw,uchar w,uchar q,uchar b,uchar s,uchar g)
{
P2=tabdu[sw];
P0=tabwe[0];
delay(5);
P0=0xff;
P2=tabdu[w];
P0=tabwe[1];
delay(5);
P0=0xff;
P2=tabdu[q];
P0=tabwe[2];
delay(5);
P0=0xff;
P2=tabdu[b];
P0=tabwe[3];
delay(5);
P0=0xff;
P2=tabdu[s];
P0=tabwe[4];
delay(5);
P0=0xff;
P2=tabdu[g];
P0=tabwe[5];
delay(5);
P0=0xff;
}
下面这个是电路图，图我没有画啊，不过我用仿真去做，应该跟电路图差不多了，你可以参考下，可以实现流水灯，闹铃，日期，时间，等功能，上面给你的是按照你的要求，另外我懒得改了所以多了个功能就是可以看日期，你看上面的程序，第一个按钮ch，按一下查看日期，再按一下查看温度（被删了，随机现在是随机显示一个数字），再按一下是流水灯，再按一下又回到时间，另外两个键key/key1；按key是选择锁定分还是时，如果你当前显示的是日期的话就是顺序锁定日，月，年，按key1调整，图上显示的是22点00分09秒，就这样了
设计方案的话..........呵呵，AT89S52+6个数码管+11.0592晶振+2个30P电容+3个按钮+1个10UF电容如图连接，你自己去写方案把，分数给那么少，就只帮你那么多了
那几个发光二极管自己加就行了
s_set bit p1.0
m_set bit p1.1
h_set bit p1.2
second equ 30h
minute equ 31h
hour equ 32h
tcnt equ 34h
org 0000h
sjmp start
org 000bh
ljmp int_t0
start:mov dptr,#table
mov hour,#0
mov minute,#0
mov second,#0
mov tcnt,#0
mov tmod,#01h
mov th0,#3ch
mov tl0,#0b0h
mov ie,#82h
setb tr0
a1:lcall display
jnb s_set,s1
jnb m_set,s2
jnb h_set,s3
ljmp a1
s1:lcall delay
jb s_set,a1
inc second
mov a,second
cjne a,#60,j0
mov second,#0
ljmp k1
s2:lcall delay
jb m_set,a1
k1:inc minute
mov a,minute
cjne a,#60,j1
mov minute,#0
ljmp k2
s3:lcall delay
jb h_set,a1
k2:inc hour
mov a,hour
cjne a,#24,j2
mov hour,#0
mov minute,#0
mov second,#0
ljmp a1
j0:jb s_set,a1
lcall display
sjmp j0
j1:jb m_set,a1
lcall display
sjmp j1
j2:jb h_set,a1
lcall display
sjmp j2
int_t0:mov th0,#3ch
mov tl0,#0b0h
inc tcnt
mov a,tcnt
cjne a,#20,retune
inc second
mov tcnt,#0
mov a,second
cjne a,#60,retune
inc minute
mov second,#0
mov a,minute
cjne a,#60,retune
inc hour
mov minute,#0
mov a,hour
cjne a,#24,retune
mov hour,#0
mov minute,#0
mov second,#0
mov tcnt,#0
retune:reti
display:mov a,second
mov b,#10
div ab
clr p3.4
movc a,@a+dptr
mov p0,a
lcall delay
setb p3.4
mov a,b
clr p3.5
movc a,@a+dptr
mov p0,a
lcall delay
setb p3.5
MOV A,MINUTE
MOV B,#10
div ab
clr p3.2
movc a,@a+dptr
mov p0,a
lcall delay
setb p3.2
mov a,b
clr p3.3
movc a,@a+dptr
mov p0,a
lcall delay
setb p3.3
mov a,hour
mov b,#10
div ab
clr p3.0
movc a,@a+dptr
mov p0,a
lcall delay
setb p3.0
mov a,b
clr p3.1
movc a,@a+dptr
mov p0,a
lcall delay
setb p3.1
ret
table:db 3fh,06h,5bh,4fh,66h
db 6dh,7dh,07h,7fh,6fh
delay:mov r6,#10
d1:mov r7,#250
djnz r7,$
djnz r6,d1
ret
end
首先确定方案，既然用51单片机首先先构造一个最小系统，然后再最小系统的基础上构建外围电路，既然是时钟，就要有显示电路，显示你可以用LED或是LCD，如果你要做特别精确地时钟，建议使用时钟芯片，要是不是也别严格可以用单片机的定时器，再下来就可以考虑电子时钟的一些功能，比如时间设定，这就需要按键了，个人的理解啊，
单片机电子钟仿真的介绍就聊到这里吧，感谢您花时间阅读，谢谢。
本文标签：单片机电子钟仿真
